1/*  Part of SWI-Prolog
   2
   3    Author:        Jan Wielemaker
   4    E-mail:        J.Wielemaker@vu.nl
   5    WWW:           http://www.swi-prolog.org
   6    Copyright (c)  2004-2013, University of Amsterdam
   7                              VU University Amsterdam
   8    All rights reserved.
   9
  10    Redistribution and use in source and binary forms, with or without
  11    modification, are permitted provided that the following conditions
  12    are met:
  13
  14    1. Redistributions of source code must retain the above copyright
  15       notice, this list of conditions and the following disclaimer.
  16
  17    2. Redistributions in binary form must reproduce the above copyright
  18       notice, this list of conditions and the following disclaimer in
  19       the documentation and/or other materials provided with the
  20       distribution.
  21
  22    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
  26    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
  30    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  32    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  33    POSSIBILITY OF SUCH DAMAGE.
  34*/
  35
  36:- module(prolog_operator,
  37        [ push_operators/1,             % +List
  38          push_operators/2,             % +List, -Undo
  39          pop_operators/0,
  40          pop_operators/1,              % +Undo
  41          push_op/3                     % Precedence, Type, Name
  42        ]).
  43
  44
  45/** <module> Manage operators
  46
  47Often, one wants to define operators to  improve the readibility of some
  48very specific code. Operators in Prolog  are global objects and changing
  49operators changes syntax and possible semantics of existing sources. For
  50this reason it is desirable  to   reset  operator declarations after the
  51code that needs them has been read.   This module defines a rather cruel
  52-but portable- method to do this.
  53
  54Usage:
  55
  56==
  57:- push_operators(
  58        [ op(900, fx, hello_world)
  59        , op(600, xf, *)
  60        ]).
  61
  62hello_world World :-
  63        ....
  64
  65:- pop_operators.
  66==
  67
  68While the above are for  source-code,   the  calls  push_operators/2 and
  69pop_operators/1 can be used  for  local   processing  where  it  is more
  70comfortable to carry the undo context around.
  71
  72NOTE: In recent versions of SWI-Prolog operators   are local to a module
  73and can be exported using the syntax   below.  This is not portable, but
  74otherwise a more structured approach for operator handling.
  75
  76==
  77:- module(mymodule,
  78          [ mypred/1,
  79            op(500, fx, myop)
  80          ]).
  81==
  82
  83@compat SWI-Prolog
  84*/
  85
  86:- thread_local
  87    operator_stack/1.
  88
  89:- meta_predicate
  90    push_operators(:),
  91    push_operators(:,-),
  92    push_op(+,+,:).
  93
  94%!  push_operators(:New) is det.
  95%!  push_operators(:New, -Undo) is det.
  96%
  97%   Installs the operators from New, where New is a list of op(Prec,
  98%   Type, :Name). The modifications to the operator table are undone
  99%   in a matching call to pop_operators/0.
 100
 101push_operators(New, Undo) :-
 102    strip_module(New, Module, Ops0),
 103    tag_ops(Ops0, Module, Ops),
 104    undo_operators(Ops, Undo),
 105    set_operators(Ops).
 106
 107push_operators(New) :-
 108    push_operators(New, Undo),
 109    asserta(operator_stack(mark-Undo)).
 110
 111%!  push_op(+Precedence, +Type, :Name) is det.
 112%
 113%   As op/3, but this call must  appear between push_operators/1 and
 114%   pop_operators/0.  The  change  is   undone    by   the  call  to
 115%   pop_operators/0
 116
 117push_op(P, T, A) :-
 118    undo_operator(op(P,T,A), Undo),
 119    op(P, T, A),
 120    asserta(operator_stack(incremental-Undo)).
 121
 122%!  pop_operators is det.
 123%
 124%   Revert all changes to the operator table realised since the last
 125%   push_operators/1.
 126
 127pop_operators :-
 128    retract(operator_stack(Mark-Undo)),
 129    set_operators(Undo),
 130    Mark == mark,
 131    !.
 132
 133%!  pop_operators(+Undo) is det.
 134%
 135%   Reset operators as pushed by push_operators/2.
 136
 137pop_operators(Undo) :-
 138    set_operators(Undo).
 139
 140tag_ops([], _, []).
 141tag_ops([op(P,Tp,N0)|T0], M, [op(P,Tp,N)|T]) :-
 142    strip_module(M:N0, M1, N1),
 143    N = M1:N1,
 144    tag_ops(T0, M, T).
 145
 146set_operators([]).
 147set_operators([H|R]) :-
 148    set_operators(H),
 149    set_operators(R).
 150set_operators(op(P,T,A)) :-
 151    op(P, T, A).
 152
 153undo_operators([], []).
 154undo_operators([O0|T0], [U0|T]) :-
 155    undo_operator(O0, U0),
 156    undo_operators(T0, T).
 157
 158undo_operator(op(_P, T, N), op(OP, OT, N)) :-
 159    current_op(OP, OT, N),
 160    same_op_type(T, OT),
 161    !.
 162undo_operator(op(P, T, [H|R]), [OH|OT]) :-
 163    !,
 164    undo_operator(op(P, T, H), OH),
 165    undo_operator(op(P, T, R), OT).
 166undo_operator(op(_, _, []), []) :- !.
 167undo_operator(op(_P, T, N), op(0, T, N)).
 168
 169same_op_type(T, OT) :-
 170    op_type(T, Type),
 171    op_type(OT, Type).
 172
 173op_type(fx,  prefix).
 174op_type(fy,  prefix).
 175op_type(xfx, infix).
 176op_type(xfy, infix).
 177op_type(yfx, infix).
 178op_type(xf,  postfix).
 179op_type(yf,  postfix).